Standart library for MT4 experts
Introduction
This article requires some knowlege of MQL scripting language. As tutorials are available at MT4 home page, I am not going to explain basics of the language here.
Instead, we are going to create an expert for MT4, making sure all little pitfalls are avoided. Also, as part of the code we are about to create is the same for all experts, we are going to move it to a separate library file, this way, if we need to edit this code, we will only have to do it in one place, instead of making the (error-prone) changes to every expert we have.
This article is about the abovementioned library file, for an example of an expert using this library, see the next article.
How it is supposed to work?
As the library we are working on is designed to be part of an expert (MTS, capable of trading without human interference), let's discuss problems, that improperly written experts may have, as well as ways to resolve them.
An expert contains 3 functions, init(), start() and deinit(), first is called after the expert is used for the first time (duting the current session), the last one is called before the expert is removed (MT4 is closed, chart containing the expert is closed, or an expert is removed from the chart. As for the start(), it is called every tick.
This is the first, and the most important of possible pitfalls, as we want our expert to work the same way during the testing and in the run time. But there are no ticks during the testing! Of course, MT4 TRIES to emulate the most probable prices, using available OHLC (Open-High-Low-Close) data, but still...
Also, if an expert is a complex one, or if we have many charts, with experts attached to them, the computer slows down.
The most common solution is to trade "at the end of the bar". It means, that we use a piece of code, located at the beginning of the start() function, to figure out, if this tick is the first tick of a new bar, and only if it is so, we run the rest of the "start", otherwise we simply stop, until the next tick.
The second thing to keep in mind is that simple fact, that at the beginning of a new bar we DO NOT know it's High, Low and Close - we only have Open. This pitfall we have already discussed in the previous article, but as this is the "favorite" beginner's error, let me repeat: the code below is incorrect:
double x = Close[0];
If you want your expert to run every tick, it is OK. In this case, the Close[0] means not "the bar's close", but simply "the last value". Same, as the High[0] simply means "the highest value since the bar's beginning, so far". Note, it is "so far", not "till theend of the bar".
As soon as you try to do testing, using historical data, the Close[0] will create a problem. Because MT4 "knows" what Close[0] is, for all the historical data. The testing will go fine, but the result will not be applicable to real time trading, as in real time trading we never know what High, Low, Close[0] are!
In our expert, we are going to use High[1], Low[1], Close[1], to make sure our trading system does not "look into the future". Open[0] is fine.
The thirt important thing is related to the fact, that, regardless the multitasking nature of MT4, you can not perform two trades simultaneously. As the mater of fact, you need to make sure one trade is complete, and only then to proceed with the second one.
This is not a big deal, if you only have one expert - a "normal" expert will not try to do few trades in a time anyway. Usually, it means, that your testing will go fine, and then, when you try to run your expert on your demo account, it will "compete" with other experts (provided you have more than one expert running) for the right to open/close/modify positions. As the result, one of the two trades will not be executed.
There is a "cure" for this "deadlock", of course. All you need, is to make sure your experts trade one after another, and never - simultaneously. To do it, we are going to use "magic numbers".
Magic number is an integer, associated with the order. We are going to extend it a little bit. For our experts, the magic number will uniquely identify a combination of an expert (expert name), a currency (say, EURUSD) and a time frame (say, H1). For example:
AnchoredMomentum:
EURJPY_H1: 1
GBPUSD_H1: 2
Channel:
EURUSD_H1: 3
EURJPY_H1: 4
USDCHF_H1: 5
GBPUSD_H1: 6
GBPJPY_H1: 7
USDJPY_H1: 8
EURGBP_H1: 9
...
The first thing our expert will do, when the start() is called, is checking the global variable ("global" variables are "visible" to all experts, so experts can use them to exchange the information). If this variable is 0, an expert assigns its unique magic number to it (this approach is called "semaphores"). From this point on, all the experts "know", that they can NOT trade - until our expert releases the semaphore. To release it, at the very end of its start() function, it should assign 0 to it.
Technically speaking, this approach should work, but we are going to add an extra level of "protection against competition between experts". We are going to assign them TIME when they are allowed to trade. Once again, it is just an extra precaution.
Let's say, our experts are fast and robust. To run, their start() function need only 1-2 seconds. Then, if we start the first expert (one with magic number equal one) at the beginning of the bar, the second at the beginning of the bar PLUS 10 seconds, the third - at the beginning of the bar PLUS 20 seconds and so on, they (most of the time) will not even try to compete for order execution.
The library
This is just a code to be included in all experts. We do not want to retype it every time, so we keep it separately. According to the coding standarts, it should be located in MT4's experts/include directory, but I prefer to have access to it from the list of experts, so I placed it to experts directory.
Note, that in addition to "trading" functions, this code also contains some "reporting" functions. They are usefull when you test your expert, trying to figure out, why is it not working.
Note also, that we use some variables here, that should be assigned values in the expert, for example, dStopLoss, dTakeProfit... It is convenient, of course, but in the same time, you need to remember, to use these names. For example, you can not use "take_profit" instead of "dTakeProfit" in your expert.
// Value of the take profit, on a chart:
// dTp = Bid - dTakeProfit;
// or
// dTp = Ask + dTakeProfit;
double dTp = 0;
// Used to deside, if this is the beginning of a new bar.
int nBars;
// An expert runs 10 * nMagic seconds after the bar end
// This way we reduce competition between experts and
// avoid deadlocks
int nDelaySeconds = 10;
// Slippage
int nSlip = 5;
// Used to calculate the size of a lot, if bUseMm is
// set to 0, the lot size is always 0.1
// We strongly recommend that you use your own
// money management system, this is just a simple
// placeholder
double dProfit = 0;
// Used to figure out if we have enough money to trade
// We strongly recommend that you use your own
// money management system, this is just a simple
// placeholder
double dInitAmount = 1000;
// A standart lot size
double dLotSize = 0.1;
// Magic number. Unique for a combination of expert -
// currency - timeframe
int nMagic = 0;
// Report is not part of the trading, but only a
// function to write transactions to a file. We
// do it once a day
bool bReportDone = false;
// This variable contains 0, or the magic number
// of currently trading expert
string strTradeSemaphore = "TradeSemaphore";
// ------
/* This function creates a file with the name,
that is unique for an expert-currency-timeframe,
and writes trading history in it.
Note, that we only same the profit of operation(s)
here. If you want to save additional information,
like order open dates or swaps, you need to modify
the code below.
The strFileName contains the file name prefix,
usually it is the name of an expert.
*/
void Report(string strFileName, int nMagic,
bool& bReportDone)
{
// Do it only during run time trading
if(IsTesting())
return;
// Save once a day, at 0 hours nMagic / 2 minutes
if(Hour() == 0 && Minute() >= nMagic / 2)
{
// Make sure it only happens once, even
// if we have 2 or more ticks satisfying
// the condition above
if(bReportDone == false)
{
int hFile = FileOpen(strFileName + "_"
+ Symbol() + "_" + Period() + ".rpt",
FILE_BIN | FILE_WRITE, ',');
string str = "CloseDateTime,Buy,Sell\r\n";
FileWriteString(hFile, str, StringLen(str));
// Write the entire trading history to the
// file.
// Note: make sure all trading history is
// available (MT4-Terminal-Account History)
for(int nCnt = 0; nCnt < HistoryTotal();
nCnt++)
{
OrderSelect(nCnt, SELECT_BY_POS,
MODE_HISTORY);
if(OrderMagicNumber() == nMagic &&
OrderType() <= OP_SELL &&
OrderSymbol() == Symbol())
{
str = TimeToStr(OrderCloseTime(),
TIME_DATE|TIME_MINUTES);
if(OrderType() == OP_BUY)
str = str + "," + OrderProfit()
+ ",0";
else
str = str + ",0," + OrderProfit();
str = str + "\r\n";
FileWriteString(hFile, str,
StringLen(str));
}
}
FileFlush(hFile);
FileClose(hFile);
bReportDone = true;
}
}
else if(Hour() != 0) // Reset the flag
bReportDone = false;
}
// ------
// A simple placeholder for a real money management
// algorythm. In expert, set bUseMm to false or
// true. A default lot size is 0.1.
double GetLotSize(double dInitFraction = 0.1,
double dProfitFraction = 0.1)
{
double dLot = 0.1;
if(bUseMm)
{
dLot = (dInitFraction * dInitAmount +
dProfitFraction * dProfit) / 1000;
dLot = MathFloor(dLot * 10) / 10;
if(dLot < 0.1)
dLot = 0.1;
}
return(dLot);
}
// ------
/* Buy() and Sell() functions use dStopLoss and
dTakeProfit, that are assigned in the expert.
We are going to try to open an order for 10 times,
because sometimes the server or the Internet
connection fails.
Note the call to SaveComment() function. If the
order was not opened, when you think it should
be, you may check the corresponding file in
experts/files directory. It will give you the
error number and some additional hints on what
happened.
Note, that it is possible to use more than one
magic number with the same
expert-currency-timeframe, in which case
you need to explicitely pass it as a
nMagicNumber parameter.
dLot is a coefficient (a multiplier) used to
increase the lot size, usually, you will use
it for trading contests, or if you are
overconfident in the performance (drawdowns)
of your expert.
*/
int Sell(string strExpertName, double dLot = 0,
int nMagicNumber = -1)
{
int nResult = -1;
if(nMagicNumber == -1)
nMagicNumber = nMagic;
if(dLot == 0)
dLotSize = GetLotSize();
else
dLotSize = dLot * GetLotSize();
// Note, that this is a simple placeholder for a
// real money management algorythm. We will discuss
// money management in a separate article.
if(AccountFreeMargin() < dLotSize * dInitAmount
|| AccountFreeMargin() < 500)
return(nResult);
double dTp;
if(dTakeProfit == 0)
dTp = 0;
else
dTp = Bid - dTakeProfit;
// We try 10 times
for(int nTry = 0; nTry < 10; nTry++)
{
SaveComment("\r\n" + Day() + "." + Month() +
"." + Year() + " " + Hour() + ":" +
Minute() + ":" + Seconds());
SaveComment(" Trying to sell, attempt " +
nTry + "\r\n");
SaveComment("\r\nAsk: " + Ask + ", StopLoss: " +
dStopLoss + ", TakeProfit: " + dTakeProfit
+ "\r\n");
nResult = OrderSend(Symbol(), OP_SELL, dLotSize, Bid,
nSlip, Bid + dStopLoss, dTp, strExpertName,
nMagicNumber, 0, OrangeRed);
// Wait 10 seconds before the next try.
Sleep(10000);
// If trade failed, refresh rates and try again
if(nResult != -1)
{
SaveComment(" successfull\r\n");
break;
}
else
{
SaveComment(" failed, error " + GetLastError()
+ "\r\n");
RefreshRates();
}
}
// If all 10 attempts failed, write additional info
// to the report file
if(nResult == -1)
{
int nError = GetLastError();
Alert(strExpertName + " sell error: " + nError
+ "\r\n" + Bid + ", " + dStopLoss + ", "
+ dTp);
SaveComment(strExpertName + " sell error: " +
nError + "\r\n" + Bid + ", " + dStopLoss +
", " + dTp);
}
return(nResult);
}
// ------
// The structure of Buy() is similar to Sell(),
// see Sell() for comments
int Buy(string strExpertName, double dLot = 0,
int nMagicNumber = -1)
{
int nResult = -1;
if(nMagicNumber == -1)
nMagicNumber = nMagic;
if(dLot == 0)
dLotSize = GetLotSize();
else
dLotSize = dLot * GetLotSize();
if(AccountFreeMargin() < dLotSize * dInitAmount
|| AccountFreeMargin() < 500)
return(nResult);
double dTp;
if(dTakeProfit == 0)
dTp = 0;
else
dTp = Ask + dTakeProfit;
for(int nTry = 0; nTry < 10; nTry++)
{
SaveComment("\r\n" + Day() + "." + Month() +
"." + Year() + " " + Hour() + ":" + Minute() +
":" + Seconds());
SaveComment(" Trying to buy, attempt " + nTry +
"\r\n");
SaveComment("\r\nBid: " + Bid + ", StopLoss: " +
dStopLoss + ", TakeProfit: " + dTakeProfit);
nResult = OrderSend(Symbol(), OP_BUY, dLotSize, Ask,
nSlip, Ask - dStopLoss, dTp, strExpertName,
nMagicNumber, 0, Aqua);
Sleep(10000);
if(nResult != -1)
{
SaveComment(" successfull\r\n");
break;
}
else
{
SaveComment(" failed, error " + GetLastError() +
"\r\n");
RefreshRates();
}
}
if(nResult == -1)
{
int nError = GetLastError();
Alert(strExpertName + " buy error: " +
nError + "\r\n" + Ask + ", " + dStopLoss +
", " + dTp);
SaveComment(strExpertName + " buy error: " +
nError + "\r\n" + Ask + ", " + dStopLoss +
", " + dTp);
}
return(nResult);
}
// ------
/* We use this function to modify orders. It uses
dTrailingStop, assigned in the expert. When the
price goes away from the stop loss more than 5
points (from the stop loss to stop loss + 5 points),
we move the stop closer to the price.
*/
void ModifyOrders()
{
if(dTrailingStop == 0)
return;
// Scan all opened orders, looking for an
// order with "our" magic number
for(int nCnt = 0; nCnt < OrdersTotal();
nCnt++)
{
OrderSelect(nCnt, SELECT_BY_POS,
MODE_TRADES);
if(OrderMagicNumber() == nMagic)
{
if(OrderType() == OP_BUY)
{
if(OrderStopLoss() < Bid -
dTrailingStop - 5 * Point)
{
OrderModify(OrderTicket(),
OrderOpenPrice(),
Bid - dTrailingStop,
OrderTakeProfit(),
0, Aqua);
// Note: we assume, that there
// is only one opened order with
// this magic number in a time.
// If it is not so, comment the
// "break".
break;
}
}
if(OrderType() == OP_SELL)
{
if(OrderStopLoss() > Ask +
dTrailingStop + 5 * Point)
{
OrderModify(OrderTicket(),
OrderOpenPrice(),
Ask + dTrailingStop,
OrderTakeProfit(),
0, OrangeRed);
break;
}
}
}
}
}
// ------
// This function determines if this is the beginning
// of a new bar. Note, that in order to avoid conflicts
// between experts, we wait few seconds after the bar
// start, the delay is unique for each expert-currency-
// timeframe
bool IsBarEnd()
{
bool bIsBarEnd = false;
if(nBars != Bars)
{
if(IsTesting() || (!IsTesting() &&
CurTime() > Time[0] + nMagic * nDelaySeconds))
{
bIsBarEnd = true;
nBars = Bars;
}
}
return(bIsBarEnd);
}
// ------
/* The magic number of the currently trading expert
(or 0) is stored in the global variable. In a cycle,
our expert tries to set its magic number to this global
variable, and when successfull, exits the cycle.
*/
void CheckTradeSemaphore()
{
if(!IsTesting())
{
while(!IsStopped())
{
GlobalVariableSetOnCondition(
strTradeSemaphore, nMagic,
0.0);
if(GlobalVariableGet(strTradeSemaphore)
== nMagic)
break;
Sleep(1000);
}
RefreshRates();
}
}
// ------
/* Attempts to close an order, for 10 times.
Comments written to the file with SaveComment()
will help you to debug the expert, if it fails
to close an order.
*/
void CloseBuy(string strExpertName)
{
int nTicket = OrderTicket();
SaveComment("\r\n\tAttempting to close long
position, ticket: " + nTicket + "\r\n");
for(int nTry = 0; nTry < 10; nTry++)
{
SaveComment(Day() + "." + Month() + "." +
Year() + " " + Hour() + ":" + Minute() +
":" + Seconds());
int nResult = OrderClose(OrderTicket(),
OrderLots(), Bid, nSlip, Aqua);
Sleep(10000);
if(nResult == -1)
{
int nError = GetLastError();
Alert(strExpertName + ", error: " + nError);
SaveComment(strExpertName + ", error: " + nError);
}
bool bClosed = true;
for(int nOrderNo = OrdersTotal() - 1;
nOrderNo >= 0; nOrderNo--)
{
OrderSelect(nOrderNo, SELECT_BY_POS, MODE_TRADES);
if(OrderTicket() == nTicket)
{
bClosed = false;
break;
}
}
if(bClosed == true)
{
SaveComment(
"\r\n\tNo more orders with this ticket No");
break;
}
else
{
SaveComment("\r\n\tOrder with this ticket
still present, trying again");
RefreshRates();
}
}
}
// ------
// Same logic as in CloseBuy()
void CloseSell(string strExpertName)
{
int nTicket = OrderTicket();
SaveComment("\r\n\tAttempting to close short position,
ticket: " + nTicket + "\r\n");
for(int nTry = 0; nTry < 10; nTry++)
{
SaveComment(Day() + "." + Month() + "." + Year() +
" " + Hour() + ":" + Minute() + ":" + Seconds());
int nResult = OrderClose(OrderTicket(),
OrderLots(), Ask, nSlip, OrangeRed);
Sleep(10000);
if(nResult == -1)
{
int nError = GetLastError();
Alert(strExpertName + ", error: " + nError);
SaveComment(strExpertName + ", error: " + nError);
}
bool bClosed = true;
for(int nOrderNo = OrdersTotal() - 1;
nOrderNo >= 0; nOrderNo--)
{
OrderSelect(nOrderNo, SELECT_BY_POS, MODE_TRADES);
if(OrderTicket() == nTicket)
{
bClosed = false;
break;
}
}
if(bClosed == true)
{
SaveComment("\r\n\tNo more orders with
this ticket No");
break;
}
else
{
SaveComment("\r\n\tOrder with this ticket still
present, trying again");
RefreshRates();
}
}
}
// ------
// Open a file with unique file name, add a string
// to the end of this file
void SaveComment(string strComment)
{
if(!IsTesting())
{
int hFile = FileOpen("__test_" + strExpert +
"_" + Symbol() + ".txt",
FILE_BIN | FILE_READ | FILE_WRITE, '\t');
FileSeek(hFile, 0, SEEK_END);
FileWriteString(hFile, strComment,
StringLen(strComment));
FileClose(hFile);
}
}
// ------
// Delete pending order, logic is the same as in
// CloseBuy()
int DeletePending()
{
int nResult = -1;
for(int nTry = 0; nTry < 10; nTry++)
{
SaveComment("\r\n" + Day() + "." + Month() +
"." + Year() + " " + Hour() + ":" +
Minute() + ":" + Seconds());
SaveComment(" Trying to delete pending " +
OrderTicket() + ", attempt " + nTry + "\r\n");
nResult = OrderDelete(OrderTicket());
Sleep(10000);
if(nResult != -1)
{
SaveComment(" successfull\r\n");
break;
}
else
SaveComment(" failed, error " +
GetLastError() + "\r\n");
}
if(nResult == -1)
{
int nError = GetLastError();
Alert(strExpert + " delete pending, error: "
+ nError + "\r\n");
SaveComment(strExpert +
" delete pending, error: " + nError + "\r\n");
}
return(nResult);
}
What is FOREX?
Choosing a platform for Forex trading
Creating an indicator for MT4
Standart library for MT4 experts
Creating an expert for MT4
| Link to us and make 20% commissions through our affiliate program |
Free Stock trading Course
The course consists of five E.mails and covers all essentials of Technical Analysis approach to Stock Trading. Compare to $$$ that you will have to pay elsewhere. All you need to do is to enter your name (nickname will do) and E.mail address in the form below.
| Free intros: |
|
|
